build.gradle

buildscript {
	repositories {
		flatDir {
			dirs '../architectury-loom/build/libs'
			dirs '../architectury-plugin/build/libs'
		}
		mavenCentral()
	}
	dependencies {
		classpath name: 'architectury-loom-1.7.9999'
		classpath "org.ow2.asm:asm:9.6"
		classpath "org.ow2.asm:asm-analysis:9.6"
		classpath "org.ow2.asm:asm-commons:9.6"
		classpath "org.ow2.asm:asm-tree:9.6"
		classpath "org.ow2.asm:asm-util:9.6"
		classpath "commons-io:commons-io:2.15.1"
		classpath "com.google.code.gson:gson:2.10.1"
		classpath "com.google.guava:guava:33.0.0-jre"
		classpath "net.fabricmc:stitch:0.6.2"
		classpath "net.fabricmc:tiny-remapper:0.10.3"
		classpath "net.fabricmc:access-widener:2.1.0"
		classpath "net.fabricmc:mapping-io:0.6.1"
		classpath "net.fabricmc:lorenz-tiny:4.0.2"
		classpath "dev.architectury:mercury:0.1.4.17"
		classpath "net.fabricmc:fabric-loom-native:0.2.0"
		classpath "org.jetbrains.kotlinx:kotlinx-metadata-jvm:0.9.0"
		classpath "net.minecraftforge:installertools:1.2.0"
		classpath "org.cadixdev:lorenz:0.5.3"
		classpath "de.oceanlabs.mcp:mcinjector:3.8.0"
		classpath "com.opencsv:opencsv:5.4"
		classpath "net.minecraftforge:DiffPatch:2.0.7"
		classpath "com.electronwill.night-config:toml:3.6.6"
		classpath "com.mojang:datafixerupper:6.0.8"
		classpath "dev.architectury:at:1.0.1"

		classpath name: 'architectury-plugin-3.4.9999'
		classpath "dev.architectury:architectury-transformer:5.2.86"
		classpath "gradle.plugin.org.jetbrains.gradle.plugin.idea-ext:gradle-idea-ext:0.10"
	}
}

plugins {
	id 'io.github.goooler.shadow' version '8.1.7' apply false
}

apply plugin: 'architectury-plugin'

architectury {
	minecraft = project.minecraftVersion
}

allprojects {
	group = rootProject.group
	version = rootProject.modVersion
}

subprojects {
	apply plugin: 'dev.architectury.loom'
	apply plugin: 'architectury-plugin'

	base {
		archivesName = "$rootProject.name-$rootProject.minecraftVersion-$project.name"
	}

	repositories {
		maven {
			name = "CurseMaven"
			url = "https://www.cursemaven.com"
		}
	}

	dependencies {
		minecraft "net.minecraft:minecraft:$rootProject.minecraftVersion"
		mappings loom.officialMojangMappings()

		modImplementation files("../libs/Iceberg-1.21-common-1.2.3.jar")
		modImplementation files("../libs/Prism-1.21-fabric-1.0.7.jar")
	}

	java {
		sourceCompatibility = JavaVersion.VERSION_21
		targetCompatibility = JavaVersion.VERSION_21
	}

	tasks.withType(JavaCompile).configureEach {
		it.options.release = 21
	}

	remapJar {
		destinationDirectory = file("$buildDir/../../output")
	}
}