build.gradle

plugins {
  id 'java-gradle-plugin'
  id 'net.researchgate.release'
  id 'maven-publish'
}

dependencies {
  compileOnly dependencyStrings.JIB_GRADLE_EXTENSION
  compileOnly dependencyStrings.GUAVA

  testImplementation dependencyStrings.JIB_GRADLE_EXTENSION
  testImplementation dependencyStrings.GUAVA
  testImplementation dependencyStrings.JUNIT
  testImplementation dependencyStrings.MOCKITO_CORE
}

jar {
  manifest {
    attributes 'Implementation-Version': version
    attributes 'Automatic-Module-Name': 'com.google.cloud.tools.jib.gradle.extension.layerfilter'

    // OSGi metadata
    attributes 'Bundle-SymbolicName': 'com.google.cloud.tools.jib.gradle.extension.layerfilter'
    attributes 'Bundle-Name': 'Layer Filter Extension for Jib Gradle Plugin'
    attributes 'Bundle-Vendor': 'Google LLC'
    attributes 'Bundle-DocURL': 'https://github.com/GoogleContainerTools/jib-extensions'
    attributes 'Bundle-License': 'https://www.apache.org/licenses/LICENSE-2.0'
    attributes 'Export-Package': 'com.google.cloud.tools.jib.*'
  }
}

/* RELEASE */
configureMavenRelease()

publishing {
  publications {
    mavenJava(MavenPublication) {
      pom {
        name = 'Layer Filter Extension for Jib Gradle Plugin'
        description = 'Allows fine-grained control of files in image layers.'
      }
      from components.java
    }
  }
}

// Release plugin (git release commits and version updates)
release {
  tagTemplate = 'v$version-jib-layer-filter-extension-gradle'
  git {
    requireBranch = /^jib-layer-filter-extension-gradle-release-v\d+.*$/  //regex
  }
}
/* RELEASE */