build.gradle

apply plugin: 'java'
apply plugin: 'maven'

version='1.0.1-SNAPSHOT'
group='com.simsilica'

repositories {
    mavenLocal()
    jcenter()
    
    // Temporary until JME jars are in jcenter()   
    maven { url "http://dl.bintray.com/jmonkeyengine/org.jmonkeyengine" }
}

// Make sure the build file declares what it actually imports
configurations.compile {
    transitive = false
}

// In this section you declare the dependencies for your production and test code
dependencies {

    compile "org.jmonkeyengine:jme3-core:3.1.+" 
    //compile "com.jme3:jme3-core:unknown" 
    compile 'org.slf4j:slf4j-api:1.7.13'

    runtime files("assets")        
}


// Configuration to produce maven-repo style -sources and -javadoc jars
task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
    exclude '**/.backups' 
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}
 
task assetsJar(type: Jar) {
    classifier = 'assets'
    from file('assets')
    exclude '**/*.psd' 
    exclude '**/.backups' 
}
 
artifacts {
    archives sourcesJar
    archives javadocJar
    archives assetsJar
}