build.gradle

group = 'com.natsumes'
version = '1.0-SNAPSHOT'

buildscript {
    ext {
        //定义一个变量，统一规定springboot的版本
        springBootVersion = '2.1.7.RELEASE'
    }
    repositories {
        maven {
            url = 'http://maven.aliyun.com/nexus/content/groups/public/'
        }
        jcenter()
        mavenCentral()
    }
    dependencies { //用来打包
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

allprojects {
    repositories {
        maven {
            url = 'http://maven.aliyun.com/nexus/content/groups/public/'
        }
        jcenter()
        mavenCentral()
    }
    //指定编码格式
    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }
}

//设定当前模块项目中的配置
subprojects {

    apply plugin: 'java'
    apply plugin: 'idea'
    //spring boot 插件
    apply plugin: 'org.springframework.boot'
    //A Gradle plugin that provides Maven-like dependency management functionality
    apply plugin: 'io.spring.dependency-management'

    group 'com.natsumes'
    version '1.0.0'

    dependencies {
        implementation('org.springframework.boot:spring-boot-starter-web')
        implementation('com.alibaba:fastjson:1.2.69')
        compileOnly('org.projectlombok:lombok')
        annotationProcessor('org.projectlombok:lombok')
        testCompile('org.springframework.boot:spring-boot-starter-test')
    }

    dependencyManagement {
        imports {
            //spring bom helps us to declare dependencies without specifying version numbers.
            mavenBom "org.springframework.boot:spring-boot-starter-parent:${springBootVersion}"
        }
    }

    jar {
        enabled = true
        manifest.attributes provider: 'gradle'
    }

    sourceCompatibility = 11
    targetCompatibility = 11
}