build.gradle

plugins {
	id 'java'
	id 'eclipse'
}

// Gson 2.10 requires Java 7, there's no point in compiling this for Java 5
targetCompatibility = 7;
sourceCompatibility = 7;

repositories {
	mavenCentral()
	maven {
		url = uri("https://repo.blueberrymc.net/repository/maven-releases/")
	}
}

jar {
	from {
		configurations.runtime.collect {
			it.isDirectory() ? it : zipTree(it)
		}
	}
	manifest {
		attributes(
			'Main-Class': 'org.betacraft.launcher.Launcher'
		)
	}
}

task osxBuildApp {
	dependsOn jar

	doLast {
		def dist = "${buildDir}/app/BetaCraft Launcher.app"
		mkdir("$dist/Contents/MacOS")
		mkdir("$dist/Contents/Resources")
		copy {
			from "${buildDir}/../src/main/app/Info.plist"
			into "$dist/Contents"
		}
		copy {
			from "${buildDir}/../src/main/app/PkgInfo"
			into "$dist/Contents"
		}
		copy {
			from "${buildDir}/../src/main/app/BetaCraft Launcher"
			into "$dist/Contents/MacOS"
		}
		copy {
			from "${buildDir}/../src/main/app/icon.icns"
			into "$dist/Contents/Resources"
		}
		copy {
			from "${buildDir}/libs/${project.name}.jar"
			into "$dist/Contents/MacOS"
		}
		exec {
			workingDir "${buildDir}/app/"
			commandLine('zip', '-rvFSX', "../libs/BetaCraft-Launcher-macOS.zip", '.')
		}
	}
}

dependencies {
	runtime 'com.google.code.gson:gson:2.10.1'

	compileOnly 'com.google.code.gson:gson:2.10.1'
	compileOnly 'net.arikia.dev:discord-rpc-without-jna:1.7.0'
}