build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.10'
    id 'org.beryx.jlink' version '2.24.1'
}

group 'com.candle'
version '0.1.1'

repositories {
    mavenCentral()
}

ext {
    junitVersion = '5.8.2'
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

application {
    mainModule = 'FileExplorer.main'
    mainClass = 'com.candle.fileexplorer.StartFilesApp'
}

javafx {
    version = '17.0.1'
    modules = ['javafx.controls', 'javafx.fxml']
}

dependencies {
    // File/IO
    implementation 'commons-io:commons-io:2.11.0'

    // Tests
    testImplementation 'org.junit.jupiter:junit-jupiter:5.8.2'
    testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")

    testImplementation 'org.mockito:mockito-core:4.6.1'
}

test {
    useJUnitPlatform()
}

jlink {
    imageZip = project.file("${buildDir}/distributions/Files-${javafx.platform.classifier}.zip")
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher {
        name = 'Files'
    }

    jpackage {
        if (org.gradle.internal.os.OperatingSystem.current().linux) {
            imageOptions = ["--icon", "src/main/resources/icons/Files.png"]
            installerOptions += ["--resource-dir", "src/main/resources/icons"]
        }
        if (org.gradle.internal.os.OperatingSystem.current().windows) {
            imageOptions = ["--icon", "src/main/resources/icons/Files.ico"]
            installerOptions += ["--resource-dir", "src/main/resources/icons"]
        }
    }
}

jlinkZip {
    group = 'distribution'
}

allprojects {
    apply plugin: 'java'

    tasks.withType(Copy).all {
        duplicatesStrategy 'exclude'
    }
}

task createProperties(dependsOn: processResources) {
    doLast {
        new File("${sourceSets.main.resources.srcDirs[0]}/version.properties").
                withWriter { w ->
            Properties p = new Properties()
            p['version'] = project.version.toString()
            p.store w, null
        }
    }
}

classes {
    dependsOn createProperties
}