build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.10'
}

group 'com.github.chamexxxx'
version '1.0'

repositories {
    mavenCentral()
}

ext {
    junitVersion = '5.7.1'
}

sourceCompatibility = '11'
targetCompatibility = '11'

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

task copyLicense {
    outputs.file new File("$buildDir/LICENSE")
    doLast {
        copy {
            from 'LICENSE'
            into "$buildDir"
        }
    }
}

applicationDistribution.from(copyLicense) {
    into ''
}

application {
    mainModule = 'com.github.chamexxxx.meetingroombookingsystem'
    mainClass = 'com.github.chamexxxx.meetingroombookingsystem.Application'
}

javafx {
    version = '11.0.2'
    modules = ['javafx.controls', 'javafx.fxml']
}

dependencies {
    implementation 'com.calendarfx:view:11.10.1'
    implementation 'org.slf4j:slf4j-simple:1.7.32'
    implementation 'org.xerial:sqlite-jdbc:3.36.0.3'
    implementation 'com.j256.ormlite:ormlite-core:5.7'
    implementation 'com.j256.ormlite:ormlite-jdbc:5.7'
    implementation 'at.favre.lib:bcrypt:0.9.0'
    implementation 'org.controlsfx:controlsfx:11.1.0'
    implementation 'org.kordamp.ikonli:ikonli-javafx:12.2.0'
    implementation 'org.kordamp.ikonli:ikonli-fluentui-pack:12.2.0'
    implementation 'com.github.javafaker:javafaker:1.0.2'
    implementation 'org.jetbrains:annotations:22.0.0'

    testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")
}

test {
    useJUnitPlatform()
}