Package for NixOS

[Congee]

Hi apple cider drinkers, I have made a package script for NixOS at Congee/nur@c00f8ef

There are some issues but Cider just works for me. I plan to submit it to the official nixpkgs if there's no issue with the packaging script. So, feedback is welcome 😁

It currently cannot use gpu acceleration on wayland due to https://github.com/ciderapp/Cider/issues/684#issuecomment-1092654923 because we are using Electron 16. Unfortunately, Electron 17 has a problem with widevine https://github.com/ciderapp/Cider/issues/553#issuecomment-1062875614 revealed as components.status() hanging indefinitely. It would be a big help if anyone can solve the widevine issue with electron 17.

Here is a build-from-scratch script if anyone is interested to debug widevine

{ stdenv
, electron_16
, fetchgit
, mkYarnPackage
, fetchYarnDeps
, makeWrapper
, lib
, glib
, atomEnv

, libuuid
, at-spi2-atk
, at-spi2-core
, libappindicator-gtk3
, libdrm
, mesa
, libxkbcommon
, libxshmfence
, libglvnd
, libXScrnSaver

, gnutar
}:
let
  version = electron_16.version;
  electronLibPath = with lib; makeLibraryPath (
    [ libuuid at-spi2-atk at-spi2-core libappindicator-gtk3 ]
    ++ optionals (! versionOlder version "9.0.0") [ libdrm mesa ]
    ++ optionals (! versionOlder version "11.0.0") [ libxkbcommon ]
    ++ optionals (! versionOlder version "12.0.0") [ libxshmfence ]
    ++ optionals (! versionOlder version "17.0.0") [ libglvnd ]
  );

  electron = electron_16.overrideAttrs (old: rec {
    postFixup = ''
      patchelf \
        --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
        --set-rpath "${atomEnv.libPath}:${electronLibPath}:$out/lib/electron" \
        $out/lib/electron/electron $out/lib/electron/chrome_crashpad_handler

      wrapProgram $out/lib/electron/electron \
        --prefix LD_PRELOAD : ${lib.makeLibraryPath [ libXScrnSaver ]}/libXss.so.1 \
        "''${gappsWrapperArgs[@]}"
    '';
  });
  electron_exec = if stdenv.isDarwin then "${electron}/Applications/Electron.app/Contents/MacOS/Electron" else "${electron}/bin/electron";
in
mkYarnPackage rec {
  pname = "Cider";
  src = fetchgit {
    url = "https://github.com/ciderapp/Cider";
    rev = "28810c600f7a6baaae38fd1583774153932563a0";
    sha256 = "sha256-+hG09Yx5UuUtICGCyYHVJJ/j6s0/sBpjU8rRkxDkTYc=";
  };

  packageJSON = ./package.json;
  yarnLock = ./yarn.lock;
  offlineCache = fetchYarnDeps {
    inherit yarnLock;
    # obtained from `$ prefetch-yarn-deps yarn.lock`
    sha256 = "1jxip8khgjv64l5n87qywddpklm864519gi50aky4jiq5rn7x5pp";
  };


  nativeBuildInputs = [ electron makeWrapper glib libglvnd ];

  buildPhase = ''
    runHook preBuild

    rm -rf deps/cider/node_modules
    cp -R $node_modules deps/cider
    chmod -R u+w deps/cider

    pushd deps/cider
    yarn build
    popd

    runHook postBuild
  '';

  installPhase = ''
    runHook preInstall

    mkdir -p $out/bin
    cp -R deps/cider/build $out
    cp -R node_modules $out/build

    cat > $out/bin/cider <<EOF
      #!${stdenv.shell}/bin/sh
      ELECTRON_ENABLE_LOGGING=true ${electron_exec} $out/build/index.js \
        --verbose \
        --debug \
        --enable-features=UseOzonePlatform --ozone-platform=wayland \
        --enable-webgl-developer-extensions \
        --enable-webgl-draft-extensions \
        --enable-accelerated-mjpeg-decode \
        --enable-accelerated-video \
        --disable-gpu-driver-bug-workarounds \
        --ignore-gpu-blacklist \
        --enable-native-gpu-memory-buffers \
        --enable-features VaapiVideoDecoder
    EOF
    chmod +x $out/bin/cider
    wrapProgram $out/bin/cider \
      --prefix PATH : `dirname ${electron_exec}`

    runHook postInstall
  '';

  distPhase = "true";
  

  meta = with lib; {
    homepage = "https://cider.sh/";
    description = "A new cross-platform Apple Music experience based on Electron and Vue.js written from scratch with performance in mind.";
    license = with licenses; [ agpl3 ];
    maintainers = with maintainers; [ congee ];
    platforms = platforms.linux;
  };
}