settings.gradle

plugins {
  id 'com.gradle.enterprise' version '3.10.2'
  id 'com.gradle.common-custom-user-data-gradle-plugin' version '1.7.2'
}

gradleEnterprise {
  if (!gradle.startParameter.isBuildScan()) {
    server = 'https://caffeine.gradle-enterprise.cloud/'
    buildScan.publishIfAuthenticated()
  }
  buildScan {
    capture.taskInputFiles = true
    publishAlways()

    if (System.env.'CI') {
      uploadInBackground = false
    } else {
      obfuscation.ipAddresses { [] }
    }
    if (System.env.'GITHUB_ACTIONS') {
      obfuscation.username { 'github' }
    }

    termsOfServiceAgree = 'yes'
    termsOfServiceUrl = 'https://gradle.com/terms-of-service'
  }
}

def gradleEnterpriseCachePassword = properties.'gradleEnterpriseCachePassword'
buildCache {
  remote(HttpBuildCache) {
    url = 'https://caffeine.gradle-enterprise.cloud/cache/'
    push = System.env.'CI'
    enabled = true
    credentials {
      username = 'ci'
      password = gradleEnterpriseCachePassword ?: System.env.'GRADLE_ENTERPRISE_CACHE_PASSWORD'
    }
  }
}

dependencyResolutionManagement.repositories {
  mavenCentral()
}

rootProject.name = 'caffeine'

include 'caffeine'
include 'guava'
include 'jcache'
include 'simulator'