build.gradle

buildscript {
    ext {
        // Dependency Versions
        nebulaReleaseVersion = "4.0.1"
        jGitVersion = "4.10.0.201712302008-r"
        javaSemVerVersion = "0.9.0"
        junitVersion = "4.12"
        mockitoVersion = "2.19.0"
        assertJVersion = "3.4.1"
    }
    repositories {
        jcenter()
    }
    dependencies {
        classpath("com.netflix.nebula:nebula-release-plugin:${nebulaReleaseVersion}")
    }
}

plugins {
    id "com.gradle.plugin-publish" version "0.10.0"
    id "java-gradle-plugin"
}
apply plugin: "groovy"
apply plugin: 'java-gradle-plugin'
apply plugin: 'idea'
apply plugin: "nebula.nebula-release"
apply plugin: 'maven'

task wrapper(type: Wrapper) {
    gradleVersion = "4.8.1"
}

repositories {
    mavenCentral()
    maven { url "https://plugins.gradle.org/m2/" }
}

version = "1.0.1"
group = "com.github.frankfarrell.blastradius"



gradlePlugin {
    plugins {
        blastRadiusPlugin {
            id = 'com.github.frankfarrell.blastradius'
            implementationClass = 'com.github.frankfarrell.blastradius.BlastRadiusPlugin'
        }
    }
}


jar {
    baseName = "blast-radius"
    archivesBaseName = "blast-radius"
    manifest {
        attributes("Implementation-Title": "Gradle plugin to determine changed modules for CD", "Implementation-Version": version)
    }
    // Include all dependent libraries in the archive "lib" directory (fat jar).
    into("lib") {
        from configurations.runtime {
            exclude "**gradle**"
            exclude "**groovy**"
        }
    }
}

dependencies {
    compile localGroovy()
    compile gradleApi()

    compile("org.eclipse.jgit:org.eclipse.jgit:${jGitVersion}")
    compile("com.github.zafarkhaja:java-semver:${javaSemVerVersion}")

    testCompile("junit:junit:${junitVersion}")
    testCompile("org.mockito:mockito-core:${mockitoVersion}")
    testCompile("org.assertj:assertj-core:${assertJVersion}")
}

// The configuration example below shows the minimum required properties
// configured to publish your plugin to the plugin portal
pluginBundle {
    website = 'https://github.com/frankfarrell/blast-radius'
    vcsUrl = 'https://github.com/frankfarrell/blast-radius'
    description = 'Gradle plugin to determine changed modules for CD'
    tags = ['cd', 'blast-radius']

    plugins {
        blastRadiusPlugin {
            displayName = 'Blast Radius Gradle plugin'
        }
    }
}