diff --git a/gnome-extra/extension-manager/Manifest b/gnome-extra/extension-manager/Manifest
index 8dff7100fa..30abd5416d 100644
--- a/gnome-extra/extension-manager/Manifest
+++ b/gnome-extra/extension-manager/Manifest
@@ -1 +1,2 @@
 DIST extension-manager-0.5.1.tar.gz 2248071 BLAKE2B 44fbd22961c462d1d3047e790e0054b77508476b927ae83b9677b7ad60df854287901c66a671c9c05d5a1f7857cf2f4dbad662604bed6322e8e02340880fa2d5 SHA512 7f5fc64adda0ea8c0d505c29d2a9037e565a42a66a2c151f5ed21267c715aa1738b94b075704fe4479961356a255c9aea450155b969a60cb78edf40ae448681f
+DIST extension-manager-0.6.0.tar.gz 2444382 BLAKE2B d45ad954ddcbd7853b90403d3947beadfda4d06f9dcd4ffabd570e625ff0365fe9df71109595c1f89dd199c283ee867314f0c7f21e095160e66b56229a782224 SHA512 cf2419c699534fae57539dc6cf86ff22afb925ba8dd7adc186e3d5c14b2cff474f487bfc16dbaac01de80c4811e73dcd0df80fe2b79db70fd409d0a56561b78a
diff --git a/gnome-extra/extension-manager/extension-manager-0.6.0.ebuild b/gnome-extra/extension-manager/extension-manager-0.6.0.ebuild
new file mode 100644
index 0000000000..8c43bb5d55
--- /dev/null
+++ b/gnome-extra/extension-manager/extension-manager-0.6.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mjakeman/extension-manager.git"
+else
+	SRC_URI="https://github.com/mjakeman/extension-manager/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A native tool for browsing, installing, and managing GNOME Shell Extensions"
+HOMEPAGE="https://mattjakeman.com/apps/extension-manager"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libxml2
+	gui-libs/gtk:4[introspection]
+	>=gui-libs/libadwaita-1.6.0:1[introspection]
+	net-libs/libsoup:3.0
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpackage="ebuild"
+		-Ddistributor="Gentoo GURU <guru-bugs@gentoo.org>"
+
+		# sys-libs/libbacktrace has been last-rited in ::gentoo
+		# and is thus unavailable
+		-Dbacktrace=false
+	)
+	if has live ${PROPERTIES}; then
+		# Produce a development build for live ebuild
+		emesonargs+=( -Ddevelopment=true )
+	fi
+	meson_src_configure
+}
+
+# Tests are skipped because as of version 0.3.0, the tests only validate
+# resource files and do not verify any functionality of the program.  Those
+# validations are either already handled by QA checks or not relevant on
+# Gentoo.  For more information about the rationale, please refer to:
+# https://github.com/gentoo/guru/commit/f896bee213fbb62c70e818c1bf503fee2a41919a#comments
+#
+# If tests are to be executed in the future because the upstream adds
+# functionality tests or for other reasons, and should there be no convenient
+# way to skip the validations, the following variable values need to be set:
+#
+# IUSE="test"
+# RESTRICT="!test? ( test )"
+# BDEPEND="test? ( dev-libs/appstream-glib dev-util/desktop-file-utils )"
+src_test() {
+	:
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}