build.gradle

import io.gitlab.arturbosch.detekt.Detekt

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext {
        androidGradlePlugin = '7.3.1'
        kotlinSerializationPlugin = '1.8.0'

        // Project
        minSdk = 23
        targetSdk = 33
        compileSdk = 33
        desugarJdkLibrary = "1.1.6"

        // Kotlin
        kotlin = "1.8.0"

        // Kotlin Coroutines
        kotlinCoroutines = "1.6.4"

        // ViewModel
        viewModelScope = "2.5.1"
        viewModelFragmentKtx = "1.5.5"

        // Android UI
        appCompat = "1.6.0"
        materialUi = "1.8.0"
        constraintLayout = "2.1.4"
        recyclerView = '1.2.1'
        swiperefresh = "1.1.0"
        navigation = "2.5.3"

        lottieAndroidView = "5.2.0"
        shimmerAndroidView = "0.5.0"
        glide = "4.14.2"

        // Jetpack Compose UI
        composeCompiler = "1.4.0"
        composeBom = "2023.01.00"
        activityCompose = "1.7.0-alpha04"
        composeConstraintLayout = "1.0.1"
        navigationCompose = "2.6.0-alpha05"

        coil = "2.2.2"
        lottieCompose = "5.2.0"
        shimmerCompose = "1.0.4"

        // DI
        dagerHilt = "2.45"
        hiltNavigation = "1.0.0"

        // Room
        room = "2.5.0"

        // Retrofit
        retrofit = "2.9.0"
        retrofitLogging = "4.9.3"
        retrofitKotlinxSerialization = "0.8.0"

        // KotlinX Serialization
        kotlinxSerialization = "1.4.1"

        // Code Style
        detekt = "1.20.0"

        // Testing
        jUnit = "4.13.2"
        jUnitAndroidX = "1.1.5"
        espresso = "3.5.1"
        mockk = "1.13.2"
        kotlinAndroidTest = "1.5.0"
        okHttp = "4.9.0"
        androidArchCore = "2.1.0"
    }
}

plugins {
    //trick: for the same plugin versions in all sub-modules
    id 'org.jetbrains.kotlin.android' version "$kotlin" apply false
    id 'com.android.application' version "$androidGradlePlugin" apply false
    id 'com.android.library' version "$androidGradlePlugin" apply false

    // Detekt
    id "io.gitlab.arturbosch.detekt" version "$detekt" apply false

    // DI
    id "com.google.dagger.hilt.android" version "$dagerHilt" apply false
}

subprojects {
    // Jetpack Compose breaches lots of code styles in Kotlin,
    // so ignoring Detekt on module with Jetpack Compose
    if (project.name != "jetpackComposeApp")
        applyDetekt(project.name)
}

def applyDetekt(projectName) {
    project(projectName) {
        // Version should be inherited from parent
        apply plugin: "io.gitlab.arturbosch.detekt"

        detekt {
            // point to your custom config defining rules to run, overwriting default behavior
            config = files("$rootDir/detekt_config.yml")
        }

        tasks.withType(Detekt).configureEach {
            reports {
                html.enabled = false
                // observe findings in your browser with structure and code snippets
                xml.enabled = false // checkstyle like format mainly for integrations like Jenkins
                txt.enabled = false
                // similar to the console output, contains issue signature to manually edit baseline files
                sarif.enabled = false
                // standardized SARIF format (https://sarifweb.azurewebsites.net/) to support integrations with Github Code Scanning
            }
        }
    }
}