Add Exec2, the "better version of Exec"

Add a new function `Exec2` which is as easy to use as `Exec` but
much more powerful and less easy to misuse:

- don't pass everything to a shell, thus avoiding compatibility
  issues due to different shells on different systems (this also
  has one downside: you can't use redirects like ">/dev/null")
- pass arguments as separate strings, thus avoiding any issues with
  quoting quotes, quoting spaces, etc.
- return the exit code of the executed command so that one can
  determine its success or failure; the return value is actually
  a record to allow returning other data, such as the programs output
- make it very easy to override the input and output streams
- by default, pass no input to the program (instead of passing
  anything the user might type, as `Exec` does); this can be
  changed by adding an input stream to the argument list
- by default, capture any output of the program into a string
  and return it, instead of just printing the output to the
  console; this can be changed by adding an output stream to
  the argument list

lib/helpview.gi

@@ -80,7 +80,7 @@ if ARCH_IS_WINDOWS() then
       winfilename:=MakeExternalFilename( SplitString( filename, "#" )[1] );
     fi;
     Print( "Opening help page ", winfilename, " in default windows browser ... \c" );
-    Exec( Concatenation("start ", winfilename ) );
+    Exec2( "start", winfilename );
     Print( "done! \n" );
   end
   );
@@ -138,7 +138,7 @@ elif ARCH_IS_MAC_OS_X() then
             fi;
             file := file.file;
           fi;
-          Exec(Concatenation("open -a Preview ", file));
+          Exec2("open", "-a", "Preview", file);
           Print("#  see page ", page, " in the Preview window.\n");
         end
     );
@@ -155,7 +155,7 @@ elif ARCH_IS_MAC_OS_X() then
             fi;
             file := file.file;
           fi;
-          Exec(Concatenation("open -a \"Adobe Reader\" ", file));
+          Exec2("open", "-a", "Adobe Reader", file);
           Print("#  see page ", page, " in the Adobe Reader window.\n");
         end
     );
@@ -172,7 +172,7 @@ elif ARCH_IS_MAC_OS_X() then
             fi;
             file := file.file;
           fi;
-          Exec(Concatenation("open ", file));
+          Exec2("open ", file);
           Print("#  see page ", page, " in the pdf viewer window.\n");
         end
     );
@@ -187,16 +187,15 @@ elif ARCH_IS_MAC_OS_X() then
                 fi;
                 file := file.file;
             fi;
-            Exec( Concatenation(
-                "osascript <<ENDSCRIPT\n",
-                    "tell application \"Skim\"\n",
-                    "activate\n",
-                    "open \"", file, "\"\n",
-                    "set theDoc to document of front window\n",
-                    "go theDoc to page ",String(page)," of theDoc\n",
-                    "end tell\n",
-                "ENDSCRIPT\n" ) );
-            return;
+            Exec2("osascript",
+                InputTextString(Concatenation("""
+                    tell application "Skim"
+                    activate
+                    open """, ViewString(file), """
+                    set theDoc to document of front window
+                    go theDoc to page """,String(page),""" of theDoc
+                    end tell
+                """)));
         end
     );
 
@@ -207,17 +206,20 @@ else # UNIX but not macOS
     HELP_VIEWER_INFO.browser := rec(
     type := "url",
     show := function( url )
+      local str;
+      str := "";
+      Exec2("wslpath", "-a", "-w", url, OutputTextString(str, false));
       # Ignoring part of the URL after '#' since we are unable
       # to navigate to the precise location on Windows
       url := SplitString( url, "#" )[1];
-      Exec(Concatenation("explorer.exe \"$(wslpath -a -w \"",url, "\")\""));
+      Exec2("explorer.exe", str);
     end
     );
 
     HELP_VIEWER_INFO.("pdf viewer") := rec(
         type := "pdf",
         show := function(file)
-          local   page;
+          local   page, str;
           # unfortunately one cannot (yet?) give a start page to windows
           page := 1;
           if IsRecord(file) then
@@ -226,7 +228,10 @@ else # UNIX but not macOS
             fi;
             file := file.file;
           fi;
-          Exec(Concatenation("explorer.exe \"$(wslpath -a -w \"",file, "\")\""));
+
+          str := "";
+          Exec2("wslpath", "-a", "-w", url, OutputTextString(str, false));
+          Exec2("explorer.exe", str);
           Print("#  see page ", page, " in PDF.\n");
     end
     );
@@ -235,15 +240,15 @@ else # UNIX but not macOS
     HELP_VIEWER_INFO.netscape := rec(
     type := "url",
     show := function(url)
-      Exec(Concatenation("netscape -remote \"openURL(file:", url, ")\""));
+      Exec2("netscape", "-remote", Concatenation("openURL(file:", url, ")"));
     end
     );
 
     # html version with mozilla
     HELP_VIEWER_INFO.mozilla := rec(
     type := "url",
     show := function(url)
-      Exec(Concatenation("mozilla -remote \"openURL(file:", url, ")\""));
+      Exec2("mozilla", "-remote", Concatenation("openURL(file:", url, ")"));
     end
     );
 
@@ -276,36 +281,36 @@ else # UNIX but not macOS
   HELP_VIEWER_INFO.lynx := rec(
   type := "url",
   show := function(url)
-    Exec(Concatenation("lynx \"", url, "\""));
+    Exec2("lynx", url);
   end
   );
 
   # html version with w3m
   HELP_VIEWER_INFO.w3m := rec(
   type := "url",
   show := function(url)
-    Exec(Concatenation("w3m \"", url, "\""));
+    Exec2("w3m", url);
   end
   );
 
   HELP_VIEWER_INFO.elinks := rec(
   type := "url",
   show := function(url)
-    Exec(Concatenation("elinks \"", url, "\""));
+    Exec2("elinks", url);
   end
   );
 
   HELP_VIEWER_INFO.links2ng := rec(
   type := "url",
   show := function(url)
-    Exec(Concatenation("links2 \"", url, "\""));
+    Exec2("links2", url);
   end
   );
 
   HELP_VIEWER_INFO.links2 := rec(
   type := "url",
   show := function(url)
-    Exec(Concatenation("links2 -g \"", url, "\""));
+    Exec2("links2", "-g", url);
   end
   );
 fi;

lib/process.gd

@@ -186,3 +186,5 @@ DeclareOperation( "Process",
 ##  <#/GAPDoc>
 ##
 DeclareGlobalFunction( "Exec" );
+
+DeclareGlobalName( "Exec2" );

lib/process.gi

@@ -261,3 +261,77 @@ InstallGlobalFunction( Exec, function( arg )
     Process( dir, shell, InputTextUser(), OutputTextUser(), [ cs, cmd ] );
 
 end );
+
+# TODO: document this, come up with a better name, write some tests...
+BindGlobal( "Exec2", function( arg )
+    local args, result, a, input, output, dir, cmd;
+
+    args := [];
+    result := rec();
+
+    # parse the inputs
+    for a in arg do
+        if IsDirectory(a) then
+            if IsBound(dir) then
+                Error("must specify at most one working directory");
+            fi;
+            dir := a;
+        elif IsInputStream(a) then
+            if IsBound(input) then
+                Error("must specify at most one input stream");
+            fi;
+            input := a;
+        elif IsOutputStream(a) then
+            if IsBound(output) then
+                Error("must specify at most one output stream");
+            fi;
+            output := a;
+        elif IsString(a) then
+            ConvertToStringRep(a);
+            if not IsBound(cmd) then
+                cmd := a;
+            else
+                Add(args, a);
+            fi;
+        else
+            Error("unsupported argument type");
+        fi;
+    od;
+
+    if not IsBound(cmd) then
+        Error("must specify a command to execute");
+    fi;
+
+    # determine full executable path if it is not already a path
+    if not '/' in cmd then
+        a := Filename( DirectoriesSystemPrograms(), cmd );
+        if a = fail and ARCH_IS_WINDOWS() then
+            a := Filename( DirectoriesSystemPrograms(), Concatenation( cmd, ".exe" ) );
+        fi;
+        if a = fail then
+            Error("could not locate executable for '", cmd, "'");
+        fi;
+        cmd := a;
+    fi;
+
+    # set default working directory if necessary
+    if not IsBound(dir) then
+        dir := DirectoryCurrent();
+    fi;
+
+    # if no input stream was specified, pass no input to the command
+    if not IsBound(input) then
+        input := InputTextNone();
+    fi;
+
+    # if no output stream was specified, put output into the returned record
+    if not IsBound(output) then
+        result.output := "";
+        output := OutputTextString(result.output, false);
+    fi;
+
+    # execute the command
+    result.status := Process( dir, cmd, input, output, args );
+
+    return result;
+end );

lib/streams.gi

@@ -1311,19 +1311,20 @@ InstallGlobalFunction( InputFromUser,
 InstallGlobalFunction( OpenExternal, function(filename)
     local file;
     if ARCH_IS_MAC_OS_X() then
-      Exec(Concatenation("open \"",filename,"\""));
+      Exec2("open", filename);
     elif ARCH_IS_WINDOWS() then
-      Exec(Concatenation("cmd /c start \"",filename,"\""));
+      Exec2("cmd", "/c", "start", filename);
     elif ARCH_IS_WSL() then
       # If users pass a URL, make sure if does not get mangled.
       if ForAny(["https://", "http://"], {pre} -> StartsWith(filename, pre)) then
         file := filename;
       else
-        file := Concatenation("$(wslpath -a -w \"",filename,"\")");
+        file := "";
+        Exec2("wslpath", "-a", "-w", filename, OutputTextString(file, false));
       fi;
-      Exec(Concatenation("explorer.exe \"", file, "\""));
+      Exec2("explorer.exe", file);
     else
-      Exec(Concatenation("xdg-open \"",filename,"\""));
+      Exec2("xdg-open", filename);
     fi;
 end );